CS001251 - Deleting a message in Flash Lite

From Forum Nokia Wiki

ID	CS001251	Creation date	December 19, 2008
Platform	S60 5th Edition	Tested on devices	Nokia 5800 XpressMusic
Category	Flash Lite	Subcategory	Messaging

Keywords (APIs, classes, methods, functions): Service.Messaging, messaging.GetList(), messaging.Delete()

Overview

This code snippet demonstrates how to delete the selected message from the Messaging inbox using the Messaging Platform Service for Flash Lite, supported from S60 5th Edition onwards.

Preconditions

Note: Using this application will remove the selected messages completely.

Source

// Import Platform Service Interface
import com.nokia.lib.Service;

/**********************************************************
** Define all variables and arrays
**********************************************************/
var outList;
var inParams;
var outParams 
var outputEntry;
var errorId;
 
var sender;
var messageType;
var bodyText;
var messageId;
 
var i = 0;
 
var idList:Array = new Array();
var senderList:Array = new Array();
var typeList:Array = new Array();
var messageList:Array = new Array();
 
// Create a new Service object which has Messaging data
var messaging = new Service("Service.Messaging", "IMessaging");
 
// Heading of the application
heading_txt.text = "Delete messages";
// Get list of the messages (Inbox)
listMessages();
// Define number of the last item
var lastItem = idList.length-1;
// Trace information of the first message to the form
setTexts();
 
/**********************************************************
** Function for setting the texts to inputs
**********************************************************/
function setTexts() {
    nro_txt.text = i+1+"/"+idList.length;
 
    if(senderList[i] == undefined) {
        sender_txt.text = "";
    } else {
        sender_txt.text = senderList[i];
    }
 
    if(typeList[i] == undefined) {
        type_txt.text = ""; 
    } else {
        type_txt.text = typeList[i];
    }
 
    if(messageList[i] == undefined) {
        message_txt.text = "";
    } else {
        message_txt.text = messageList[i];
    }
}
 
/**********************************************************
** Function for getting an updated list of the messages
**********************************************************/
function listMessages() {
 
    // Define input parameters
    inParams = {Type:"Inbox"};
 
    // Define result value
    outParams = messaging.GetList(inParams);
    if (outParams.ErrorCode == 0) {
        // Go through all messages (Inbox)
        outList = outParams.ReturnValue;
        outputEntry = null;
        idList = [];
        senderList = [];
        typeList = [];
        messageList = [];
        do {
            outputEntry = outList.next();
            if (null != outputEntry) {
                idList.push(outputEntry.MessageId);
                senderList.push(outputEntry.Sender);
                typeList.push(outputEntry.MessageType);
                messageList.push(outputEntry.BodyText);
            } else {
              break;
            }
        } while (true);
        error_txt.text = idList.length+" messages found";
 
    } else {
        errorId = outParams.ErrorCode;
        error_txt.text = "Error 1: "+errorId;
    }
}
 
/**********************************************************
** Function for pressing the Prev button
**********************************************************/
prev_mc.onPress = function() {
    if(i == 0) {
        i = lastItem;
    } else {
        i--;
    }
    setTexts();
    error_txt.text = "";
}
 
/**********************************************************
** Function for pressing the Next button
**********************************************************/
next_mc.onPress = function() {
    if(i == lastItem) {
        i = 0;
    } else {
        i++;
    }
    setTexts();
    error_txt.text = "";
}
 
/**********************************************************
** Fuction for deleting the message when Delete button is pressed.
** NOTE! Deleting the message with this application will
** erase the massage completely
**********************************************************/
delete_mc.onPress = function() {
    messageId = idList[i];
    inParams = {MessageId:messageId};
    outParams = messaging.Delete(inParams);
    if (outParams.ErrorCode == 0) {
        error_txt.text = "Message Deleted";
        i = 0;
        listMessages();
        // Define number of the last item
        var lastItem = idList.length-1;
        // Trace information of the contact to the form
        setTexts();
    } else {
        errorId = outParams.ErrorCode;
        error_txt.text = "Error 2: "+errorId;
    }
 
}
 
/**********************************************************
** Function for pressing the Exit button.
**********************************************************/
exit_mc.onPress = function() {
    status = fscommand2("Quit");
    trace("QUIT");
}

Postconditions

You can browse and remove all the messages. Sender, message type, and body text information are displayed.

Example application

The following sample application has been tested in Nokia 5800 XpressMusic (S60 5th edition, Flash Lite 3.0).
File:FlashLite Removing a Message.zip

Community: Wiki